Cách tạo ra một file flash bằng LaTeX

Trước hết ta xem một flash tại địa chỉ
http://melusine.eu.org/syracuse/metapost/animations/ellipse2/

Trong mặt phẳng Oxy cho một elip có phương trình:

\dfrac{x^2}{a^2}+\dfrac{y^2}{b^2}=1

Chứng minh rằng tập hợp các điểm mà từ đó vẽ được hai tiếp tuyến vuông góc tới elip là đường tròn:

x^2+y^2=a^2+b^2

mà ta gọi là đường tròn Monge.

 

 

Để thực hiện flash trên ta cần chuẩn bị các công việc sau đây:

  • Một file metapost. Sau này ta phải tự viết một file metapost, ở đây ta lấy file mẫu.
  • Một chương trình tên là Swftools. Chương trình này chạy được trên MS Windows và trên Linux.

1. Sau đây là file monge.mp được download từ website nêu trên:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
%@Auteur: Maxime Chupin
 
verbatimtex 
%&latex 
\documentclass{article} 
\usepackage[latin1]{inputenc}
\usepackage{amsmath}
\usepackage{fourier}
\begin{document} 
etex 
 
input geometrie2d;
u=3cm;
v=3;
 
path r;
path carre;
carre = (0,0)--(1,0)--(1,1)--(0,1)--cycle;
 
for i=0 upto 72:
    beginfig(i+1);
 
    % excentricité : 0.65
 
    numeric a,b,c,e,ya,xa,yb,xb,w,m,xm,ym;
    e := 0.65;
    a := 1.3u;
    b := a*sqrt(1-e**2);
    c := a*e;
    pair M,T,F,H,A,B,M';
    path ellipse,tangente,monge,tang,arc,vraitang;
    ellipse = fullcircle xscaled 2a yscaled 2b;
 
    % axes
    pickup pencircle scaled 0.6pt;
    draw(-5u,0)--(5u,0);
    draw(0,-5u)--(0,5u);
    pickup pencircle scaled 1pt;
    draw ellipse withcolor green;
    drawarrow (0,0)--(0.6u,0);
    drawarrow (0,0)--(0,0.6u);
    pickup pencircle scaled 0.5pt;
 
    % directrice
    z3=(a/e,0);
    z4=(a/e,2u);
    draw 5[z3,z4]--5[z4,z3];
    z6=(-a/e,0);
    z7=(-a/e,2u);
    draw 5[z6,z7]--5[z7,z6];
 
    % M
    xm:=a*cosd(30+5*i);
    ym:=b*sind(30+5*i);
    M = (xm,ym);
 
    %tangente en M
 path tangente;
 
 
    if (xm<>0) and (ym<>0):
   ya=0;
   xa=a*a/xm;
 
   yb=b*b/ym;
   xb=0;
    fi;
 
    if (ym=0) and (xm<>0):
   ya=0;
   xa=(a*a)/xm;
 
   yb=2u;
   xb=(a*a)/xm;
    fi;
 
    if (xm=0) and (ym<>0):
   xa=0;
   ya=(b*b)/ym;
 
   xb=2u;
   yb=(b*b)/ym;
    fi;
 
    %définition de daux points de coordonnés xa,ya et xb,yb
    A = (xa,ya);
    B = (xb,yb);
 
    % cercle de monge
    monge := fullcircle scaled 2sqrt(a*a+b*b);
 
 
 
    pickup pencircle scaled 0.8pt;
    % tracé de la droite
    draw 10[A,B]--10[B,A] withcolor blue;
    tangente := 10[A,B]--10[B,A];
 
 
    % point d'intersection
    arc := halfcircle scaled 2sqrt(a*a+b*b) rotated (15+5*i) ;
    T = arc intersectionpoint tangente;
 
    % tracé du cercle
 
    if i=0:
 r := T;
    else:
 r := r--T;
 draw r withcolor red;
    fi;
 
 
    % tangente en M'
    F=(0,0);
    if (xm<>0) and (ym<>0): 
 w=1*u;
 m=(a*a)/(b*b)*ym/xm*u;
    fi;
 
    if (xm=0) and (ym<>0):
 w=0;
 m=2u;
    fi;
 
    if (ym=0) and (xm<>0):
 w=2u;
 m=0;
    fi;
 
    z2=(w,m);
    H=z2;
    tang = 5[F,H]--5[H,F];
    vraitang := tang shifted T;
    draw tang shifted T withcolor blue;
    % z5= vraitang intersectionpoint ellipse;
 
 
    %carré
    pickup pencircle scaled 0.7pt;
    draw carre scaled 10 rotated (angle(T-M)+90) shifted T
 dashed evenly withcolor 0.2white;
 
 
    % labels
 
    % i,j
    label.bot(btex $\vec \imath$ etex, (0.3u,0));
    label.lft(btex $\vec \jmath$ etex, (-0.01u,0.3u));
 
    % points
    % label.lft(btex $M'$ etex, z5);
    dotlabel.urt(btex $T$ etex, T);
    dotlabel.urt(btex $M$ etex, M);
    dotlabel.urt(btex $O$ etex, (0,0));
    % droites
    label.lft(btex $\delta$ etex,(0,-1.8u));
    label.lft(btex $\cal D$ etex,(-2u,-1.8u));
    label.rt(btex ${\cal D}'$ etex,(2u,-1.8u));
 
    % titre
    label.urt(btex \begin{LARGE}\textit{Le cercle de Monge}\end{LARGE} etex, (-1.5*a,1.3*a)); 
    label.urt(btex \begin{LARGE}$x^2+y^2=a^2+b^2$\end{LARGE} etex, (0.3*a,1.3*a)); 
 
    clip currentpicture to 
 (-2.5u,-2u)--(-2.5u,2u)--(2.5u,2u)--(2.5u,-2u)--cycle;
    endfig;
endfor;
 
end

Do câu lệnh ở dòng 20 mà khi chạy lệnh

mpost monge.mp, metapost  sẽ tự động tạo ra 73 hình được đánh số từ monge.1 đến monge.73.
2. Soạn một file TeX như sau save thành monge.tex

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
\documentclass{article}
\usepackage[utf8]{inputenc}
\usepackage[vietnam]{babel}
\usepackage{amsmath}
\usepackage{amsfonts}
\usepackage{amssymb}
\usepackage[paperwidth=16cm,paperheight=12.5cm,
left=.2cm,right=.2cm,top=.2cm,bottom=.2cm]{geometry}
\usepackage{graphicx}
\DeclareGraphicsRule{*}{mps}{*}{}
\usepackage{multido} 
\begin{document}
\pagestyle{empty}
\multido{\n=1+1}{73}{
\includegraphics[scale=1]{monge.\n}\newpage }
\end{document}

Biên dịch file này bằng pdflatex monge.tex thành monge.pdf

3. Các bạn download Swftools về cài đặt vào một thư mục tên là Swftools, copy thư mục này ra Desktop .

Mở một cửa sổ dòng lệnh, vào thư mục nói trên chạy lệnh:

pdf2swf monge.pdf -o temp.swf

Sau đó chạy tiếp lệnh

swfcombine -dz -r 30 temp.swf -o monge.swf

muốn flash chạy nhanh hay chậm ta tăng hoặc giảm con số sau -r.

4. Các bạn sử dụng các chương trình vận hành file swf sẽ thấy flash chạy trơn tru.

6 responses to “Cách tạo ra một file flash bằng LaTeX

  1. Cám ơn Thầy nhiều ạ!

  2. Kính chào Thầy!
    Geogebra cũng có thể vẽ được phải không Thầy?

  3. Thầy có thể chia sẻ kinh nghiệm cài swftools một cách hoàn thiện không?

    • download phần mềm tại
      http://www.swftools.org/swftools-2013-04-09-1007.exe

      1. Nhấn đúp vào file swftools-2013-04-09-1007.exe đề cài đặt. Chương trình sẽ tự động cài đặt, nhưng chỉ có pdf2swf là chạy ở chế độ đồ họa.

      2. Vì swftools là một bộ công cụ gồm nhiều thứ nên ta chạy các chương trình này ở chế độ console. Sau khi cài xong, em tìm thư mục swftools để copy file pdf vào thư mục này.

      3. em bấm start, chọn lệnh cmd để mở màn hình giao diện dòng lệnh. Em ra lệnh cd chuyển thư mục đến thư mục swftools. Tai đây em chạy pdf2swf để tách file pdf ra từng khung ảnh của các chương trình swf thông dụng.

      Sau đó em dùng lệnh swfcombine để nhập các khung ảnh thành một file flash swf.

      Cách dùng pdf2swf và swfcombine thầy đã hướng dẫn.

  4. Em cài swftools trên Ubuntu mà không được . nếu Thầy cài trên Ubuntu thành công mong thầy chia sẽ.

Gửi phản hồi

Mời bạn điền thông tin vào ô dưới đây hoặc kích vào một biểu tượng để đăng nhập:

WordPress.com Logo

Bạn đang bình luận bằng tài khoản WordPress.com Log Out / Thay đổi )

Twitter picture

Bạn đang bình luận bằng tài khoản Twitter Log Out / Thay đổi )

Facebook photo

Bạn đang bình luận bằng tài khoản Facebook Log Out / Thay đổi )

Google+ photo

Bạn đang bình luận bằng tài khoản Google+ Log Out / Thay đổi )

Connecting to %s