Tại sao không vẽ hình bằng metapost? – Bài 2

Bài tập 2:

Khai báo ba đỉnh và chân đường cao kẻ từ A bằng tọa độ của chúng:

    A = Point(3,7.5);
    B = Point(0,0);
    C = Point(9,0);
    H = Point(3,0);

Sau đó ta định nghĩa T là tam giác ABC, c là đường tròn ngoại tiếp tam giác T, O là tâm của c và A’ là điểm xuyên tâm đối.

    T = Triangle(A,B,C);
    c = CercleCirconscrit(T);
    O = Centre(c);
    A'= Symetrique(A,O);

Lần lượt vẽ các hình vừa dịnh nghĩa ở trên gồm tam giác và đường tròn ngoại tiếp:

 trace T
	withcolor (0,0.39,0)
	withpen pencircle scaled 1.5;

    trace c
	withcolor black;

Tiếp theo vẽ đường cao AH, đường kính AA’ và nối BA’

trace Segment(A,H)
    withcolor red;

    trace Segment(B,A')
    withcolor 0.4red;
    trace Segment(A,A')
    withcolor 0.4red;

Vẽ ký hiệu góc vuông chỗ hai đường thẳng vuông góc

trace SigneOrtho(A,H,C,0.2);
    trace SigneOrtho(A,B,A',0.2);

Đặt tên cho các điểm trong hình vẽ

marque.top "A";
    marque.lft "B";
    marque.lrt "C";
    marque.bot "H";
    marque.urt "O";
    marque.bot "A'";

Gọi R là trung điểm đoạn thẳng OA, sau đó hiển thị chữ “R” vào hình vẽ với vị trí thích hợp

 R = Milieu(Segment(A,O));
    Etiquette.urt("$R$",1,_Point(R));

Sau đây là code của hình vẽ. Các bạn copy và dán vào TeXMaker lưu thành file bt2.mp

input geometrie2d;

beginfig(1);

    A = Point(3,7.5);
    B = Point(0,0);
    C = Point(9,0);
    H = Point(3,0);
    T = Triangle(A,B,C);
    c = CercleCirconscrit(T);
    O = Centre(c);
    A'= Symetrique(A,O);

    trace T
	withcolor (0,0.39,0)
	withpen pencircle scaled 1.5;

    trace c
	withcolor black;

    trace Segment(A,H)
	withcolor red;

    trace Segment(B,A')
	withcolor 0.4red;
    trace Segment(A,A')
	withcolor 0.4red;

    trace SigneOrtho(A,H,C,0.2);
    trace SigneOrtho(A,B,A',0.2);

    marque.top "A";
    marque.lft "B";
    marque.lrt "C";
    marque.bot "H";
    marque.urt "O";
    marque.bot "A'";
    R = Milieu(Segment(A,O));
    Etiquette.urt("$R$",1,_Point(R));
endfig;
end

Khi đã có code bt2.mp các bạn biên dịch sang hình vẽ bằng lệnh

mpost bt2.mp

Kết quả ta có một file hình tên là bt2.1

Muốn chèn hình vẽ này vào văn bản, trong file TeX phải có khai báo trước \begin{document}

\usepackage{graphicx}
\DeclareGraphicsRule{*}{mps}{*}{}

Muốn hiển thi hình vẽ các bạn viết

\includegraphics[scale=1]{bt2.1}

Muốn xem hình vẽ này để điều chỉnh nếu cần các bạn soạn một file TeX như sau:

\documentclass[12pt,a4paper]{book}
\usepackage[utf8]{inputenc}
\usepackage[vietnam]{babel}
\usepackage{amsmath}
\usepackage{amsfonts}
\usepackage{amssymb}
\usepackage{graphicx}
\DeclareGraphicsRule{*}{mps}{*}{}
\begin{document}
\pagestyle{empty}
\includegraphics[scale=1]{bt2.1}
\end{document}

lưu thành file bt2.tex và biên dịch bằng

pdflatex bt2.tex

Tuần sau:

Gửi phản hồi

Mời bạn điền thông tin vào ô dưới đây hoặc kích vào một biểu tượng để đăng nhập:

WordPress.com Logo

Bạn đang bình luận bằng tài khoản WordPress.com Log Out / Thay đổi )

Twitter picture

Bạn đang bình luận bằng tài khoản Twitter Log Out / Thay đổi )

Facebook photo

Bạn đang bình luận bằng tài khoản Facebook Log Out / Thay đổi )

Google+ photo

Bạn đang bình luận bằng tài khoản Google+ Log Out / Thay đổi )

Connecting to %s